Datei:MaxwellBoltzmann gases T0C.png
Größe dieser Vorschau: 600 × 600 Pixel. Weitere Auflösungen: 240 × 240 Pixel | 480 × 480 Pixel | 768 × 768 Pixel | 1.024 × 1.024 Pixel.
Originaldatei (1.024 × 1.024 Pixel, Dateigröße: 43 KB, MIME-Typ: image/png)
Beschreibung
Maxwell-Boltzmann distribution for different gases at T=0°C. Multi-language suitable. Created with gnuplot 4.4; source code below :
#set term postscript enhanced eps color "Helvetica" 24
set term png truecolor enhanced font "Helvetica,36" size 1024,1024
set out "mb_T0.png"
# physics constants (in SI)
k = 1.38e-23
NA= 6.022e23
u = 0.001 / NA
T0 = 273.15
# Maxwell-Boltzmann distribution (mass in atomic units u, v in SI)
p(v,m,T) = 4. *pi * v**2. * (m*u/(2.*pi*k*T))**1.5 * exp( -m * u * v**2. / (2.*k*T))
# Formatting
set samples 10000
set key Left reverse at graph 0.9, 0.75
set yrange [0:.0022]
set xtics 1000 nomirror offset 0,0.25
set ytics nomirror 0.5e-3
set format y ""; set label 10 "10^{-3}" at -400,1.e-3
set border 3
set grid
set xlabel "v (m/s)" offset 13.5,2
set ylabel "p(v) (s/m)" offset 1, 5
set style fill transparent solid 0.4
# Plot for different gases at zero Celsius
set xrange [0:3900]
set label 11 "T = 0 °C" at graph 0.35, 0.8
plot p(x,28,T0) t "N_{2} (m=28 u)" w filledcurve x1, \
p(x,4,T0) t "He (m=4 u)" w filledcurve x1, \
p(x,2,T0) t "H_{2} (m=2 u)" w filledcurve x1
Lizenz
Ich, der Urheber dieses Werkes, veröffentliche es unter der folgenden Lizenz:
 
|
Diese Datei wird unter der Creative-Commons-Lizenz „CC0 1.0 Verzicht auf das Copyright“ zur Verfügung gestellt. |
| Die Person, die das Werk mit diesem Dokument verbunden hat, übergibt dieses weltweit der Gemeinfreiheit, indem sie alle Urheberrechte und damit verbundenen weiteren Rechte – im Rahmen der jeweils geltenden gesetzlichen Bestimmungen – aufgibt. Das Werk kann – selbst für kommerzielle Zwecke – kopiert, modifiziert und weiterverteilt werden, ohne hierfür um Erlaubnis bitten zu müssen.
|
Dateiversionen
Klicke auf einen Zeitpunkt, um diese Version zu laden.
| Version vom | Vorschaubild | Maße | Benutzer | Kommentar | |
|---|---|---|---|---|---|
| aktuell | 07:23, 24. Jun. 2013 | | 1.024 × 1.024 (43 KB) | wikimediacommons>TDF | Fix: He instead of He2 |
Dateiverwendung
Die folgende Seite verwendet diese Datei:
